" ___vital___
" NOTE: lines between '" ___vital___' is generated by :Vitalize.
" Do not mofidify the code nor insert new lines before '" ___vital___'
if v:version > 703 || v:version == 703 && has('patch1170')
  function! vital#_easymotion#Over#Commandline#Modules#Redraw#import() abort
    return map({'make': ''},  'function("s:" . v:key)')
  endfunction
else
  function! s:_SID() abort
    return matchstr(expand('<sfile>'), '<SNR>\zs\d\+\ze__SID$')
  endfunction
  execute join(['function! vital#_easymotion#Over#Commandline#Modules#Redraw#import() abort', printf("return map({'make': ''}, \"function('<SNR>%s_' . v:key)\")", s:_SID()), 'endfunction'], "\n")
  delfunction s:_SID
endif
" ___vital___
scriptencoding utf-8
let s:save_cpo = &cpo
set cpo&vim


let s:module = {
\	"name" : "Redraw",
\}

function! s:module.on_execute_pre(cmdline)
	call self.redraw(a:cmdline)
endfunction

function! s:module.on_enter(...)
	let self.is_execute = 0
endfunction

function! s:module.on_execute(...)
	let self.is_execute = 1
endfunction

function! s:module.on_execute_failed(...)
	let self.is_execute = 0
endfunction

function! s:module.on_leave(cmdline)
	if self.is_execute == 0 && a:cmdline.exit_code() != -1
		call self.redraw(a:cmdline)
	endif
endfunction


" function! s:module.on_draw_pre(cmdline)
" 	call self.redraw(a:cmdline)
" endfunction


function! s:module.redraw(cmdline)
	redraw
	" Workaround for the :set cedit=<C-c>
	" https://github.com/osyo-manga/vital-over/issues/52
	" https://github.com/Lokaltog/vim-easymotion/issues/177#issuecomment-53663431
	if &cedit != "<C-c>"
\	||(v:version >= 704 && has("patch441"))
		normal! :
	else
		execute "normal! :\<Esc>"
	endif
endfunction

function! s:make()
	return deepcopy(s:module)
endfunction


let &cpo = s:save_cpo
unlet s:save_cpo