475f337b5f
First, it should not break anything: according to tmux's ChangeLog, then tmux support for bracketed-paste mode dates back to 1.7. Then, on my (tmux 2.1) system, WrapForTmux actually makes the char codes be ignored, and a tmux error file is written. I couldn't find a trace in tmux's ChangeLog as to when this occured, and so went with switching on the major tmux version.
43 lines
1.3 KiB
VimL
43 lines
1.3 KiB
VimL
" Code from:
|
|
" http://stackoverflow.com/questions/5585129/pasting-code-into-terminal-window-into-vim-on-mac-os-x
|
|
" then https://coderwall.com/p/if9mda
|
|
" and then https://github.com/aaronjensen/vimfiles/blob/59a7019b1f2d08c70c28a41ef4e2612470ea0549/plugin/terminaltweaks.vim
|
|
" to fix the escape time problem with insert mode.
|
|
"
|
|
" Docs on bracketed paste mode:
|
|
" http://www.xfree86.org/current/ctlseqs.html
|
|
" Docs on mapping fast escape codes in vim
|
|
" http://vim.wikia.com/wiki/Mapping_fast_keycodes_in_terminal_Vim
|
|
|
|
if !exists("g:bracketed_paste_tmux_wrap")
|
|
let g:bracketed_paste_tmux_wrap = 1
|
|
endif
|
|
|
|
function! WrapForTmux(s)
|
|
if !g:bracketed_paste_tmux_wrap || !exists('$TMUX') || system('tmux -V')[5] >= '2'
|
|
return a:s
|
|
endif
|
|
|
|
let tmux_start = "\<Esc>Ptmux;"
|
|
let tmux_end = "\<Esc>\\"
|
|
|
|
return tmux_start . substitute(a:s, "\<Esc>", "\<Esc>\<Esc>", 'g') . tmux_end
|
|
endfunction
|
|
|
|
let &t_ti .= WrapForTmux("\<Esc>[?2004h")
|
|
let &t_te .= WrapForTmux("\<Esc>[?2004l")
|
|
|
|
function! XTermPasteBegin(ret)
|
|
set pastetoggle=<f29>
|
|
set paste
|
|
return a:ret
|
|
endfunction
|
|
|
|
execute "set <f28>=\<Esc>[200~"
|
|
execute "set <f29>=\<Esc>[201~"
|
|
map <expr> <f28> XTermPasteBegin("i")
|
|
imap <expr> <f28> XTermPasteBegin("")
|
|
vmap <expr> <f28> XTermPasteBegin("c")
|
|
cmap <f28> <nop>
|
|
cmap <f29> <nop>
|