3694908d05
(1) Checkers now have an _exec attribute, and an accessor getExec(). (2) CreateAndRegisterChecker() initializes _exec from an optional argument 'exec'. If this argument is missing, 'name' is used instead. (3) Functions SyntaxCheckers_*_IsAvailable() are now dictionary functions. (4) Functions SyntaxCheckers_*_IsAvailable() are now optional. When they are missing, they are assumed to return executable(expand(self.getExec())). (5) Argument 'exe' of function syntastic#makeprg#build() is now optional. If this argument is missing, expand(self.getExec()) is used to set checker executables.
52 lines
1.8 KiB
VimL
52 lines
1.8 KiB
VimL
"============================================================================
|
|
"File: slim.vim
|
|
"Description: Syntax checking plugin for syntastic.vim
|
|
"Maintainer: Martin Grenfell <martin.grenfell at gmail dot com>
|
|
"License: This program is free software. It comes without any warranty,
|
|
" to the extent permitted by applicable law. You can redistribute
|
|
" it and/or modify it under the terms of the Do What The Fuck You
|
|
" Want To Public License, Version 2, as published by Sam Hocevar.
|
|
" See http://sam.zoy.org/wtfpl/COPYING for more details.
|
|
"
|
|
"============================================================================
|
|
|
|
if exists("g:loaded_syntastic_slim_slimrb_checker")
|
|
finish
|
|
endif
|
|
let g:loaded_syntastic_slim_slimrb_checker=1
|
|
|
|
function! s:SlimrbVersion()
|
|
if !exists('s:slimrb_version')
|
|
let s:slimrb_version = syntastic#util#getVersion('slimrb --version 2>' . syntastic#util#DevNull())
|
|
endif
|
|
return s:slimrb_version
|
|
endfunction
|
|
|
|
function! SyntaxCheckers_slim_slimrb_GetLocList() dict
|
|
let makeprg = syntastic#makeprg#build({
|
|
\ 'args': '-c',
|
|
\ 'checker': self })
|
|
|
|
if syntastic#util#versionIsAtLeast(s:SlimrbVersion(), [1,3,1])
|
|
let errorformat =
|
|
\ '%C\ %#%f\, Line %l\, Column %c,'.
|
|
\ '%-G\ %.%#,'.
|
|
\ '%ESlim::Parser::SyntaxError: %m,'.
|
|
\ '%+C%.%#'
|
|
else
|
|
let errorformat =
|
|
\ '%C\ %#%f\, Line %l,'.
|
|
\ '%-G\ %.%#,'.
|
|
\ '%ESlim::Parser::SyntaxError: %m,'.
|
|
\ '%+C%.%#'
|
|
endif
|
|
|
|
return SyntasticMake({
|
|
\ 'makeprg': makeprg,
|
|
\ 'errorformat': errorformat })
|
|
endfunction
|
|
|
|
call g:SyntasticRegistry.CreateAndRegisterChecker({
|
|
\ 'filetype': 'slim',
|
|
\ 'name': 'slimrb'})
|