3694908d05
(1) Checkers now have an _exec attribute, and an accessor getExec(). (2) CreateAndRegisterChecker() initializes _exec from an optional argument 'exec'. If this argument is missing, 'name' is used instead. (3) Functions SyntaxCheckers_*_IsAvailable() are now dictionary functions. (4) Functions SyntaxCheckers_*_IsAvailable() are now optional. When they are missing, they are assumed to return executable(expand(self.getExec())). (5) Argument 'exe' of function syntastic#makeprg#build() is now optional. If this argument is missing, expand(self.getExec()) is used to set checker executables.
82 lines
2.4 KiB
VimL
82 lines
2.4 KiB
VimL
"============================================================================
|
|
"File: sh.vim
|
|
"Description: Syntax checking plugin for syntastic.vim
|
|
"Maintainer: Gregor Uhlenheuer <kongo2002 at gmail dot com>
|
|
"License: This program is free software. It comes without any warranty,
|
|
" to the extent permitted by applicable law. You can redistribute
|
|
" it and/or modify it under the terms of the Do What The Fuck You
|
|
" Want To Public License, Version 2, as published by Sam Hocevar.
|
|
" See http://sam.zoy.org/wtfpl/COPYING for more details.
|
|
"
|
|
"============================================================================
|
|
|
|
if exists("g:loaded_syntastic_sh_sh_checker")
|
|
finish
|
|
endif
|
|
let g:loaded_syntastic_sh_sh_checker=1
|
|
|
|
function! s:GetShell()
|
|
if !exists('b:shell') || b:shell == ''
|
|
let b:shell = ''
|
|
let shebang = getbufline(bufnr('%'), 1)[0]
|
|
if len(shebang) > 0
|
|
if match(shebang, 'bash') >= 0
|
|
let b:shell = 'bash'
|
|
elseif match(shebang, 'zsh') >= 0
|
|
let b:shell = 'zsh'
|
|
elseif match(shebang, 'sh') >= 0
|
|
let b:shell = 'sh'
|
|
endif
|
|
endif
|
|
" try to use env variable in case no shebang could be found
|
|
if b:shell == ''
|
|
let b:shell = fnamemodify(expand('$SHELL'), ':t')
|
|
endif
|
|
endif
|
|
return b:shell
|
|
endfunction
|
|
|
|
function! s:ForwardToZshChecker()
|
|
let registry = g:SyntasticRegistry.Instance()
|
|
if registry.checkable('zsh')
|
|
return registry.getChecker('zsh', 'zsh').getLocListRaw()
|
|
else
|
|
return []
|
|
endif
|
|
|
|
endfunction
|
|
|
|
function! s:IsShellValid()
|
|
return len(s:GetShell()) > 0 && executable(s:GetShell())
|
|
endfunction
|
|
|
|
|
|
function! SyntaxCheckers_sh_sh_IsAvailable() dict
|
|
return s:IsShellValid()
|
|
endfunction
|
|
|
|
function! SyntaxCheckers_sh_sh_GetLocList() dict
|
|
if s:GetShell() == 'zsh'
|
|
return s:ForwardToZshChecker()
|
|
endif
|
|
|
|
if !s:IsShellValid()
|
|
return []
|
|
endif
|
|
|
|
let makeprg = syntastic#makeprg#build({
|
|
\ 'exe': s:GetShell(),
|
|
\ 'args': '-n',
|
|
\ 'checker': self })
|
|
|
|
let errorformat = '%f: line %l: %m'
|
|
|
|
return SyntasticMake({
|
|
\ 'makeprg': makeprg,
|
|
\ 'errorformat': errorformat })
|
|
endfunction
|
|
|
|
call g:SyntasticRegistry.CreateAndRegisterChecker({
|
|
\ 'filetype': 'sh',
|
|
\ 'name': 'sh' })
|