3694908d05
(1) Checkers now have an _exec attribute, and an accessor getExec(). (2) CreateAndRegisterChecker() initializes _exec from an optional argument 'exec'. If this argument is missing, 'name' is used instead. (3) Functions SyntaxCheckers_*_IsAvailable() are now dictionary functions. (4) Functions SyntaxCheckers_*_IsAvailable() are now optional. When they are missing, they are assumed to return executable(expand(self.getExec())). (5) Argument 'exe' of function syntastic#makeprg#build() is now optional. If this argument is missing, expand(self.getExec()) is used to set checker executables.
59 lines
1.9 KiB
VimL
59 lines
1.9 KiB
VimL
"============================================================================
|
|
"File: pyflakes.vim
|
|
"Description: Syntax checking plugin for syntastic.vim
|
|
"Authors: Martin Grenfell <martin.grenfell@gmail.com>
|
|
" kstep <me@kstep.me>
|
|
" Parantapa Bhattacharya <parantapa@gmail.com>
|
|
"
|
|
"============================================================================
|
|
if exists("g:loaded_syntastic_python_pyflakes_checker")
|
|
finish
|
|
endif
|
|
let g:loaded_syntastic_python_pyflakes_checker=1
|
|
|
|
function! SyntaxCheckers_python_pyflakes_GetHighlightRegex(i)
|
|
if match(a:i['text'], 'is assigned to but never used') > -1
|
|
\ || match(a:i['text'], 'imported but unused') > -1
|
|
\ || match(a:i['text'], 'undefined name') > -1
|
|
\ || match(a:i['text'], 'redefinition of') > -1
|
|
\ || match(a:i['text'], 'referenced before assignment') > -1
|
|
\ || match(a:i['text'], 'duplicate argument') > -1
|
|
\ || match(a:i['text'], 'after other statements') > -1
|
|
\ || match(a:i['text'], 'shadowed by loop variable') > -1
|
|
|
|
" fun with Python's %r: try "..." first, then '...'
|
|
let terms = split(a:i['text'], '"', 1)
|
|
if len(terms) > 2
|
|
return terms[1]
|
|
endif
|
|
|
|
let terms = split(a:i['text'], "'", 1)
|
|
if len(terms) > 2
|
|
return terms[1]
|
|
endif
|
|
endif
|
|
return ''
|
|
endfunction
|
|
|
|
function! SyntaxCheckers_python_pyflakes_GetLocList() dict
|
|
let makeprg = syntastic#makeprg#build({
|
|
\ 'exe': 'pyflakes',
|
|
\ 'checker': self })
|
|
|
|
let errorformat =
|
|
\ '%E%f:%l: could not compile,'.
|
|
\ '%-Z%p^,'.
|
|
\ '%E%f:%l:%c: %m,'.
|
|
\ '%E%f:%l: %m,'.
|
|
\ '%-G%.%#'
|
|
|
|
return SyntasticMake({
|
|
\ 'makeprg': makeprg,
|
|
\ 'errorformat': errorformat,
|
|
\ 'defaults': {'text': "Syntax error"} })
|
|
endfunction
|
|
|
|
call g:SyntasticRegistry.CreateAndRegisterChecker({
|
|
\ 'filetype': 'python',
|
|
\ 'name': 'pyflakes'})
|