3694908d05
(1) Checkers now have an _exec attribute, and an accessor getExec(). (2) CreateAndRegisterChecker() initializes _exec from an optional argument 'exec'. If this argument is missing, 'name' is used instead. (3) Functions SyntaxCheckers_*_IsAvailable() are now dictionary functions. (4) Functions SyntaxCheckers_*_IsAvailable() are now optional. When they are missing, they are assumed to return executable(expand(self.getExec())). (5) Argument 'exe' of function syntastic#makeprg#build() is now optional. If this argument is missing, expand(self.getExec()) is used to set checker executables.
45 lines
1.6 KiB
VimL
45 lines
1.6 KiB
VimL
"============================================================================
|
|
"File: podchecker.vim
|
|
"Description: Syntax checking plugin for syntastic.vim
|
|
"Maintainer: LCD 47 <lcd047 at gmail dot com>
|
|
"License: This program is free software. It comes without any warranty,
|
|
" to the extent permitted by applicable law. You can redistribute
|
|
" it and/or modify it under the terms of the Do What The Fuck You
|
|
" Want To Public License, Version 2, as published by Sam Hocevar.
|
|
" See http://sam.zoy.org/wtfpl/COPYING for more details.
|
|
"
|
|
"============================================================================
|
|
if exists("g:loaded_syntastic_pod_podchecker_checker")
|
|
finish
|
|
endif
|
|
let g:loaded_syntastic_pod_podchecker_checker=1
|
|
|
|
function! SyntaxCheckers_pod_podchecker_GetLocList() dict
|
|
let makeprg = syntastic#makeprg#build({ 'checker': self })
|
|
|
|
let errorformat =
|
|
\ '%W%[%#]%[%#]%[%#] WARNING: %m at line %l in file %f,' .
|
|
\ '%W%[%#]%[%#]%[%#] WARNING: %m at line EOF in file %f,' .
|
|
\ '%E%[%#]%[%#]%[%#] ERROR: %m at line %l in file %f,' .
|
|
\ '%E%[%#]%[%#]%[%#] ERROR: %m at line EOF in file %f'
|
|
|
|
let loclist = SyntasticMake({
|
|
\ 'makeprg': makeprg,
|
|
\ 'errorformat': errorformat,
|
|
\ 'returns': [0, 1, 2] })
|
|
|
|
for n in range(len(loclist))
|
|
let e = loclist[n]
|
|
if e['valid'] && e['lnum'] == 0
|
|
let e['lnum'] = str2nr(matchstr(e['text'], '\m\<line \zs\d\+\ze'))
|
|
endif
|
|
endfor
|
|
|
|
return loclist
|
|
endfunction
|
|
|
|
call g:SyntasticRegistry.CreateAndRegisterChecker({
|
|
\ 'filetype': 'pod',
|
|
\ 'name': 'podchecker'})
|
|
|