3694908d05
(1) Checkers now have an _exec attribute, and an accessor getExec(). (2) CreateAndRegisterChecker() initializes _exec from an optional argument 'exec'. If this argument is missing, 'name' is used instead. (3) Functions SyntaxCheckers_*_IsAvailable() are now dictionary functions. (4) Functions SyntaxCheckers_*_IsAvailable() are now optional. When they are missing, they are assumed to return executable(expand(self.getExec())). (5) Argument 'exe' of function syntastic#makeprg#build() is now optional. If this argument is missing, expand(self.getExec()) is used to set checker executables.
56 lines
1.8 KiB
VimL
56 lines
1.8 KiB
VimL
"============================================================================
|
|
"File: prettycss.vim
|
|
"Description: Syntax checking plugin for syntastic.vim
|
|
"Maintainer: LCD 47 <lcd047 at gmail dot com>
|
|
"License: This program is free software. It comes without any warranty,
|
|
" to the extent permitted by applicable law. You can redistribute
|
|
" it and/or modify it under the terms of the Do What The Fuck You
|
|
" Want To Public License, Version 2, as published by Sam Hocevar.
|
|
" See http://sam.zoy.org/wtfpl/COPYING for more details.
|
|
"
|
|
"============================================================================
|
|
"
|
|
" For details about PrettyCSS see:
|
|
"
|
|
" - http://fidian.github.io/PrettyCSS/
|
|
" - https://github.com/fidian/PrettyCSS
|
|
|
|
if exists("g:loaded_syntastic_css_prettycss_checker")
|
|
finish
|
|
endif
|
|
let g:loaded_syntastic_css_prettycss_checker=1
|
|
|
|
function! SyntaxCheckers_css_prettycss_GetHighlightRegex(item)
|
|
let term = matchstr(a:item["text"], '\m (\zs[^)]\+\ze)$')
|
|
if term != ''
|
|
let term = '\V' . term
|
|
endif
|
|
return term
|
|
endfunction
|
|
|
|
function! SyntaxCheckers_css_prettycss_GetLocList() dict
|
|
let makeprg = syntastic#makeprg#build({ 'checker': self })
|
|
|
|
" Print CSS Lint's error/warning messages from compact format. Ignores blank lines.
|
|
let errorformat =
|
|
\ '%EError: %m\, line %l\, char %c),' .
|
|
\ '%WWarning: %m\, line %l\, char %c),' .
|
|
\ '%-G%.%#'
|
|
|
|
let loclist = SyntasticMake({
|
|
\ 'makeprg': makeprg,
|
|
\ 'errorformat': errorformat,
|
|
\ 'defaults': {'bufnr': bufnr("")},
|
|
\ 'postprocess': ['sort'] })
|
|
|
|
for n in range(len(loclist))
|
|
let loclist[n]["text"] .= ')'
|
|
endfor
|
|
|
|
return loclist
|
|
endfunction
|
|
|
|
call g:SyntasticRegistry.CreateAndRegisterChecker({
|
|
\ 'filetype': 'css',
|
|
\ 'name': 'prettycss'})
|