"============================================================================
"File:        haskell.vim
"Description: Syntax checking plugin for syntastic.vim
"Maintainer:  Anthony Carapetis <anthony.carapetis at gmail dot com>
"License:     This program is free software. It comes without any warranty,
"             to the extent permitted by applicable law. You can redistribute
"             it and/or modify it under the terms of the Do What The Fuck You
"             Want To Public License, Version 2, as published by Sam Hocevar.
"             See http://sam.zoy.org/wtfpl/COPYING for more details.
"
"============================================================================
if exists("loaded_haskell_syntax_checker")
    finish
endif
let loaded_haskell_syntax_checker = 1

if executable("hdevtools")
    let s:checker = 'hdevtools'
elseif executable("ghc-mod")
    let s:checker = 'ghc-mod'
else
    finish
endif

if !exists('g:syntastic_haskell_checker_args')
    let g:syntastic_haskell_checker_args = '--hlintOpt="--language=XmlSyntax"'
endif

function! SyntaxCheckers_haskell_GetLocList()
    if s:checker == 'ghc-mod'
        let ghcmod = 'ghc-mod ' . g:syntastic_haskell_checker_args
        let makeprg =
              \ "{ ".
              \ ghcmod . " check ". shellescape(expand('%')) . "; " .
              \ ghcmod . " lint " . shellescape(expand('%')) . ";" .
              \ " }"
        let errorformat = '%-G\\s%#,%f:%l:%c:%trror: %m,%f:%l:%c:%tarning: %m,'.
                    \ '%f:%l:%c: %trror: %m,%f:%l:%c: %tarning: %m,%f:%l:%c:%m,'.
                    \ '%E%f:%l:%c:,%Z%m,'
    elseif s:checker == 'hdevtools'
        let makeprg = 'hdevtools check ' . get(g:, 'hdevtools_options', '') . ' ' . shellescape(expand('%'))

        let errorformat= '\%-Z\ %#,'.
                    \ '%W%f:%l:%c:\ Warning:\ %m,'.
                    \ '%E%f:%l:%c:\ %m,'.
                    \ '%E%>%f:%l:%c:,'.
                    \ '%+C\ \ %#%m,'.
                    \ '%W%>%f:%l:%c:,'.
                    \ '%+C\ \ %#%tarning:\ %m,'

    endif

    return SyntasticMake({ 'makeprg': makeprg, 'errorformat': errorformat })
endfunction

function! SyntaxCheckers_lhaskell_GetLocList()
    return SyntaxCheckers_haskell_GetLocList()
endfunction