From 28c24b350f2116c08ab9dc1dd36b270e1e2635d5 Mon Sep 17 00:00:00 2001
From: Steven Myint <git@stevenmyint.com>
Date: Fri, 27 Dec 2013 07:32:54 -0800
Subject: [PATCH] Add rstcheck

It checks reStructuredText like "rst2pseudoxml.vim" does, but
additionally rstcheck checks syntax of code blocks within RST files.

https://github.com/myint/rstcheck
---
 syntax_checkers/rst/rstcheck.vim | 46 ++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 syntax_checkers/rst/rstcheck.vim

diff --git a/syntax_checkers/rst/rstcheck.vim b/syntax_checkers/rst/rstcheck.vim
new file mode 100644
index 00000000..f98b97c3
--- /dev/null
+++ b/syntax_checkers/rst/rstcheck.vim
@@ -0,0 +1,46 @@
+"============================================================================
+"File:        rstcheck.vim
+"Description: Syntax checking for reStructuredText and embedded code blocks
+"Authors:     Steven Myint <git@stevenmyint.com>
+"
+"============================================================================
+
+" https://github.com/myint/rstcheck
+"
+" To install rstcheck:
+"     $ pip install --upgrade rstcheck
+
+if exists("g:loaded_syntastic_rst_rstcheck_checker")
+    finish
+endif
+let g:loaded_syntastic_rst_rstcheck_checker=1
+
+function! SyntaxCheckers_rst_rstcheck_GetLocList() dict
+    let makeprg = self.makeprgBuild({})
+
+    let errorformat =
+        \ '%f:%l: (%tNFO/1) %m,'.
+        \ '%f:%l: (%tARNING/2) %m,'.
+        \ '%f:%l: (%tRROR/3) %m,'.
+        \ '%f:%l: (%tEVERE/4) %m,'.
+        \ '%-G%.%#'
+
+    let loclist = SyntasticMake({
+        \ 'makeprg': makeprg,
+        \ 'errorformat': errorformat })
+
+    for e in loclist
+        if e['type'] ==? 'S'
+            let e['type'] = 'E'
+        elseif e['type'] ==? 'I'
+            let e['type'] = 'W'
+            let e['subtype'] = 'Style'
+        endif
+    endfor
+
+    return loclist
+endfunction
+
+call g:SyntasticRegistry.CreateAndRegisterChecker({
+    \ 'filetype': 'rst',
+    \ 'name': 'rstcheck'})