234 lines
7.6 KiB
VimL
234 lines
7.6 KiB
VimL
|
" ============================================================================
|
||
|
|
" File: nerdtree_fs_menu.vim
|
||
|
|
" Description: plugin for the NERD Tree that provides a file system menu
|
||
|
|
" Maintainer: Martin Grenfell <martin_grenfell at msn dot com>
|
||
|
|
" Last Change: 17 July, 2009
|
||
|
|
" License: This program is free software. It comes without any warranty,
|
||
|
|
" to the extent permitted by applicable law. You can redistribute
|
||
|
|
" it and/or modify it under the terms of the Do What The Fuck You
|
||
|
|
" Want To Public License, Version 2, as published by Sam Hocevar.
|
||
|
|
" See http://sam.zoy.org/wtfpl/COPYING for more details.
|
||
|
|
"
|
||
|
|
" ============================================================================
|
||
|
|
if exists("g:loaded_nerdtree_fs_menu")
|
||
|
|
finish
|
||
|
|
endif
|
||
|
|
let g:loaded_nerdtree_fs_menu = 1
|
||
|
|
|
||
|
|
call NERDTreeAddMenuItem('(f)ilesystem menu', 'f', 'NERDTreeShowFilesystemMenu')
|
||
|
|
|
||
|
|
"FUNCTION: s:echo(msg){{{1
|
||
|
|
function! s:echo(msg)
|
||
|
|
redraw
|
||
|
|
echomsg "NERDTree: " . a:msg
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
"FUNCTION: s:echoWarning(msg){{{1
|
||
|
|
function! s:echoWarning(msg)
|
||
|
|
echohl warningmsg
|
||
|
|
call s:echo(a:msg)
|
||
|
|
echohl normal
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
"FUNCTION: s:promptToDelBuffer(bufnum, msg){{{1
|
||
|
|
"prints out the given msg and, if the user responds by pushing 'y' then the
|
||
|
|
"buffer with the given bufnum is deleted
|
||
|
|
"
|
||
|
|
"Args:
|
||
|
|
"bufnum: the buffer that may be deleted
|
||
|
|
"msg: a message that will be echoed to the user asking them if they wish to
|
||
|
|
" del the buffer
|
||
|
|
function! s:promptToDelBuffer(bufnum, msg)
|
||
|
|
echo a:msg
|
||
|
|
if nr2char(getchar()) ==# 'y'
|
||
|
|
exec "silent bdelete! " . a:bufnum
|
||
|
|
endif
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
"FUNCTION: NERDTreeShowFilesystemMenu(){{{1
|
||
|
|
function! NERDTreeShowFilesystemMenu()
|
||
|
|
let prompt = "NERDTree Filesystem Menu\n" .
|
||
|
|
\ "==========================================================\n".
|
||
|
|
\ "Select the desired operation: \n" .
|
||
|
|
\ " (a)dd a childnode\n".
|
||
|
|
\ " (m)ove the current node\n".
|
||
|
|
\ " (d)elete the current node\n"
|
||
|
|
if g:NERDTreePath.CopyingSupported()
|
||
|
|
let prompt = prompt . " (c)opy the current node\n\n"
|
||
|
|
else
|
||
|
|
let prompt = prompt . " \n"
|
||
|
|
endif
|
||
|
|
|
||
|
|
echo prompt
|
||
|
|
|
||
|
|
let choice = nr2char(getchar())
|
||
|
|
|
||
|
|
if choice ==? "a"
|
||
|
|
call s:create()
|
||
|
|
elseif choice ==? "m"
|
||
|
|
call s:move()
|
||
|
|
elseif choice ==? "d"
|
||
|
|
call s:delete()
|
||
|
|
elseif choice ==? "c" && g:NERDTreePath.CopyingSupported()
|
||
|
|
call s:copy()
|
||
|
|
endif
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
"FUNCTION: s:create(){{{1
|
||
|
|
function! s:create()
|
||
|
|
let curDirNode = g:NERDTreeDirNode.GetSelected()
|
||
|
|
|
||
|
|
let newNodeName = input("Add a childnode\n".
|
||
|
|
\ "==========================================================\n".
|
||
|
|
\ "Enter the dir/file name to be created. Dirs end with a '/'\n" .
|
||
|
|
\ "", curDirNode.path.strForGlob() . g:NERDTreePath.Slash())
|
||
|
|
|
||
|
|
if newNodeName ==# ''
|
||
|
|
call s:echo("Node Creation Aborted.")
|
||
|
|
return
|
||
|
|
endif
|
||
|
|
|
||
|
|
try
|
||
|
|
let newPath = g:NERDTreePath.Create(newNodeName)
|
||
|
|
let parentNode = b:NERDTreeRoot.findNode(newPath.getPathTrunk())
|
||
|
|
|
||
|
|
let newTreeNode = g:NERDTreeFileNode.New(newPath)
|
||
|
|
if parentNode.isOpen || !empty(parentNode.children)
|
||
|
|
call parentNode.addChild(newTreeNode, 1)
|
||
|
|
call NERDTreeRender()
|
||
|
|
call newTreeNode.putCursorHere(1, 0)
|
||
|
|
endif
|
||
|
|
catch /^NERDTree/
|
||
|
|
call s:echoWarning("Node Not Created.")
|
||
|
|
endtry
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
"FUNCTION: s:move(){{{1
|
||
|
|
function! s:move()
|
||
|
|
let curNode = g:NERDTreeFileNode.GetSelected()
|
||
|
|
if curNode ==# {}
|
||
|
|
call s:echo("Put the cursor on a node first" )
|
||
|
|
return
|
||
|
|
endif
|
||
|
|
|
||
|
|
let newNodePath = input("Rename the current node\n" .
|
||
|
|
\ "==========================================================\n" .
|
||
|
|
\ "Enter the new path for the node: \n" .
|
||
|
|
\ "", curNode.path.strForOS(0))
|
||
|
|
|
||
|
|
if newNodePath ==# ''
|
||
|
|
call s:echo("Node Renaming Aborted.")
|
||
|
|
return
|
||
|
|
endif
|
||
|
|
|
||
|
|
try
|
||
|
|
let bufnum = bufnr(curNode.path.str(0))
|
||
|
|
|
||
|
|
call curNode.rename(newNodePath)
|
||
|
|
call NERDTreeRender()
|
||
|
|
|
||
|
|
"if the node is open in a buffer, ask the user if they want to
|
||
|
|
"close that buffer
|
||
|
|
if bufnum != -1
|
||
|
|
let prompt = "\nNode renamed.\n\nThe old file is open in buffer ". bufnum . (bufwinnr(bufnum) ==# -1 ? " (hidden)" : "") .". Delete this buffer? (yN)"
|
||
|
|
call s:promptToDelBuffer(bufnum, prompt)
|
||
|
|
endif
|
||
|
|
|
||
|
|
call curNode.putCursorHere(1, 0)
|
||
|
|
|
||
|
|
redraw
|
||
|
|
catch /^NERDTree/
|
||
|
|
call s:echoWarning("Node Not Renamed.")
|
||
|
|
endtry
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
" FUNCTION: s:delete() {{{1
|
||
|
|
function! s:delete()
|
||
|
|
let currentNode = g:NERDTreeFileNode.GetSelected()
|
||
|
|
if currentNode ==# {}
|
||
|
|
call s:echo("Put the cursor on a node first")
|
||
|
|
return
|
||
|
|
endif
|
||
|
|
|
||
|
|
let confirmed = 0
|
||
|
|
|
||
|
|
if currentNode.path.isDirectory
|
||
|
|
let choice =input("Delete the current node\n" .
|
||
|
|
\ "==========================================================\n" .
|
||
|
|
\ "STOP! To delete this entire directory, type 'yes'\n" .
|
||
|
|
\ "" . currentNode.path.strForOS(0) . ": ")
|
||
|
|
let confirmed = choice ==# 'yes'
|
||
|
|
else
|
||
|
|
echo "Delete the current node\n" .
|
||
|
|
\ "==========================================================\n".
|
||
|
|
\ "Are you sure you wish to delete the node:\n" .
|
||
|
|
\ "" . currentNode.path.strForOS(0) . " (yN):"
|
||
|
|
let choice = nr2char(getchar())
|
||
|
|
let confirmed = choice ==# 'y'
|
||
|
|
endif
|
||
|
|
|
||
|
|
|
||
|
|
if confirmed
|
||
|
|
try
|
||
|
|
call currentNode.delete()
|
||
|
|
call NERDTreeRender()
|
||
|
|
|
||
|
|
"if the node is open in a buffer, ask the user if they want to
|
||
|
|
"close that buffer
|
||
|
|
let bufnum = bufnr(currentNode.path.str(0))
|
||
|
|
if buflisted(bufnum)
|
||
|
|
let prompt = "\nNode deleted.\n\nThe file is open in buffer ". bufnum . (bufwinnr(bufnum) ==# -1 ? " (hidden)" : "") .". Delete this buffer? (yN)"
|
||
|
|
call s:promptToDelBuffer(bufnum, prompt)
|
||
|
|
endif
|
||
|
|
|
||
|
|
redraw
|
||
|
|
catch /^NERDTree/
|
||
|
|
call s:echoWarning("Could not remove node")
|
||
|
|
endtry
|
||
|
|
else
|
||
|
|
call s:echo("delete aborted")
|
||
|
|
endif
|
||
|
|
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
" FUNCTION: s:copy() {{{1
|
||
|
|
function! s:copy()
|
||
|
|
let currentNode = g:NERDTreeFileNode.GetSelected()
|
||
|
|
if currentNode ==# {}
|
||
|
|
call s:echo("Put the cursor on a file node first")
|
||
|
|
return
|
||
|
|
endif
|
||
|
|
|
||
|
|
let newNodePath = input("Copy the current node\n" .
|
||
|
|
\ "==========================================================\n" .
|
||
|
|
\ "Enter the new path to copy the node to: \n" .
|
||
|
|
\ "", currentNode.path.str(0))
|
||
|
|
|
||
|
|
if newNodePath != ""
|
||
|
|
"strip trailing slash
|
||
|
|
let newNodePath = substitute(newNodePath, '\/$', '', '')
|
||
|
|
|
||
|
|
let confirmed = 1
|
||
|
|
if currentNode.path.copyingWillOverwrite(newNodePath)
|
||
|
|
call s:echo("Warning: copying may overwrite files! Continue? (yN)")
|
||
|
|
let choice = nr2char(getchar())
|
||
|
|
let confirmed = choice ==# 'y'
|
||
|
|
endif
|
||
|
|
|
||
|
|
if confirmed
|
||
|
|
try
|
||
|
|
let newNode = currentNode.copy(newNodePath)
|
||
|
|
call NERDTreeRender()
|
||
|
|
call newNode.putCursorHere(0, 0)
|
||
|
|
catch /^NERDTree/
|
||
|
|
call s:echoWarning("Could not copy node")
|
||
|
|
endtry
|
||
|
|
endif
|
||
|
|
else
|
||
|
|
call s:echo("Copy aborted.")
|
||
|
|
endif
|
||
|
|
redraw
|
||
|
|
endfunction
|
||
|
|
|
||
|
|
" vim: set sw=4 sts=4 et fdm=marker:
|