5d6b4ef73f
The output format used by older checkstyle versions differs from the one of new versions. This commit adds a second parsing iteration on the output lines with a suitable pattern to support both versions in parallel. Due to the differences in the order of matching groups this is hard to achieve in a single pass through the output lines. An appropriate test case is added.
50 lines
1.4 KiB
VimL
50 lines
1.4 KiB
VimL
" Author: Devon Meunier <devon.meunier@gmail.com>
|
|
" Description: checkstyle for Java files
|
|
|
|
function! ale_linters#java#checkstyle#Handle(buffer, lines) abort
|
|
let l:output = []
|
|
|
|
" modern checkstyle versions
|
|
let l:pattern = '\v\[(WARN|ERROR)\] [a-zA-Z]?:?[^:]+:(\d+):(\d+)?:? (.*) \[(.+)\]$'
|
|
|
|
for l:match in ale#util#GetMatches(a:lines, l:pattern)
|
|
call add(l:output, {
|
|
\ 'type': l:match[1] is? 'WARN' ? 'W' : 'E',
|
|
\ 'lnum': l:match[2] + 0,
|
|
\ 'col': l:match[3] + 0,
|
|
\ 'text': l:match[4],
|
|
\ 'code': l:match[5],
|
|
\})
|
|
endfor
|
|
|
|
" old checkstyle versions
|
|
let l:pattern = '\v(.+):(\d+): ([^:]+): (.+)$'
|
|
|
|
for l:match in ale#util#GetMatches(a:lines, l:pattern)
|
|
call add(l:output, {
|
|
\ 'type': l:match[3] is? 'warning' ? 'W' : 'E',
|
|
\ 'lnum': l:match[2] + 0,
|
|
\ 'text': l:match[4],
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
function! ale_linters#java#checkstyle#GetCommand(buffer) abort
|
|
return 'checkstyle '
|
|
\ . ale#Var(a:buffer, 'java_checkstyle_options')
|
|
\ . ' %t'
|
|
endfunction
|
|
|
|
if !exists('g:ale_java_checkstyle_options')
|
|
let g:ale_java_checkstyle_options = '-c /google_checks.xml'
|
|
endif
|
|
|
|
call ale#linter#Define('java', {
|
|
\ 'name': 'checkstyle',
|
|
\ 'executable': 'checkstyle',
|
|
\ 'command_callback': 'ale_linters#java#checkstyle#GetCommand',
|
|
\ 'callback': 'ale_linters#java#checkstyle#Handle',
|
|
\})
|