56e67c5811
When set to true, and the buffer is currently inside a pipenv,
GetExecutable will return "pipenv", which will trigger the existing
functionality to append the correct pipenv arguments to run each linter.
Defaults to false.
I was going to implement ale#python#PipenvPresent by invoking
`pipenv --venv` or `pipenv --where`, but it seemed to be abominably
slow, even to the point where the test suite wasn't even finishing
("Tried to run tests 3 times"). The diff is:
diff --git a/autoload/ale/python.vim b/autoload/ale/python.vim
index 7baae079..8c100d41 100644
--- a/autoload/ale/python.vim
+++ b/autoload/ale/python.vim
@@ -106,5 +106,9 @@ endfunction
" Detects whether a pipenv environment is present.
function! ale#python#PipenvPresent(buffer) abort
- return findfile('Pipfile.lock', expand('#' . a:buffer . ':p:h') . ';') isnot# ''
+ let l:cd_string = ale#path#BufferCdString(a:buffer)
+ let l:output = systemlist(l:cd_string . 'pipenv --where')[0]
+ " `pipenv --where` returns the path to the dir containing the Pipfile
+ " if in a pipenv, or some error text otherwise.
+ return strpart(l:output, 0, 18) !=# "No Pipfile present"
endfunction
Using vim's `findfile` is much faster, behaves correctly in the majority
of situations, and also works reliably when the `pipenv` command doesn't
exist.
50 lines
1.5 KiB
VimL
50 lines
1.5 KiB
VimL
" Author: w0rp <devw0rp@gmail.com>
|
|
" Description: pyflakes for python files
|
|
|
|
call ale#Set('python_pyflakes_executable', 'pyflakes')
|
|
call ale#Set('python_pyflakes_use_global', get(g:, 'ale_use_global_executables', 0))
|
|
call ale#Set('python_pyflakes_auto_pipenv', 0)
|
|
|
|
function! ale_linters#python#pyflakes#GetExecutable(buffer) abort
|
|
if ale#Var(a:buffer, 'python_pyflakes_auto_pipenv') && ale#python#PipenvPresent(a:buffer)
|
|
return 'pipenv'
|
|
endif
|
|
|
|
return ale#python#FindExecutable(a:buffer, 'python_pyflakes', ['pyflakes'])
|
|
endfunction
|
|
|
|
function! ale_linters#python#pyflakes#GetCommand(buffer) abort
|
|
let l:executable = ale_linters#python#pyflakes#GetExecutable(a:buffer)
|
|
|
|
let l:exec_args = l:executable =~? 'pipenv$'
|
|
\ ? ' run pyflakes'
|
|
\ : ''
|
|
|
|
return ale#Escape(l:executable)
|
|
\ . l:exec_args
|
|
\ . ' %t'
|
|
endfunction
|
|
|
|
function! ale_linters#python#pyflakes#Handle(buffer, lines) abort
|
|
let l:pattern = '\v^[a-zA-Z]?:?[^:]+:(\d+):(\d+)?:? (.+)$'
|
|
let l:output = []
|
|
|
|
for l:match in ale#util#GetMatches(a:lines, l:pattern)
|
|
call add(l:output, {
|
|
\ 'lnum': l:match[1] + 0,
|
|
\ 'col': l:match[2] + 0,
|
|
\ 'text': l:match[3],
|
|
\})
|
|
endfor
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('python', {
|
|
\ 'name': 'pyflakes',
|
|
\ 'executable_callback': 'ale_linters#python#pyflakes#GetExecutable',
|
|
\ 'command_callback': 'ale_linters#python#pyflakes#GetCommand',
|
|
\ 'callback': 'ale_linters#python#pyflakes#Handle',
|
|
\ 'output_stream': 'both',
|
|
\})
|