Handle cython warning with custom handle and remove '--warning-errors'.

Add a custom handler to support cython warning format.
Remove '--warning-errors' to keep previous behaviour.

ale_linters/pyrex/cython.vim

@@ -3,7 +3,7 @@
 " Description: cython syntax checking for cython files.
 
 call ale#Set('pyrex_cython_executable', 'cython')
-call ale#Set('pyrex_cython_options', '--warning-extra --warning-errors')
+call ale#Set('pyrex_cython_options', '--warning-extra')
 
 function! ale_linters#pyrex#cython#GetExecutable(buffer) abort
     return ale#Var(a:buffer, 'pyrex_cython_executable')
@@ -18,10 +18,26 @@ function! ale_linters#pyrex#cython#GetCommand(buffer) abort
     \   . ' --output-file ' . g:ale#util#nul_file . ' %t'
 endfunction
 
+function! ale_linters#pyrex#cython#Handle(buffer, lines) abort
+    let l:pattern = '\v^(\w+: )?[^:]+:(\d+):?(\d+)?:? ?(.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \   'text': l:match[4],
+        \   'type': l:match[1][0] is# 'w' ? 'W' : 'E',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
 call ale#linter#Define('pyrex', {
 \   'name': 'cython',
 \   'output_stream': 'stderr',
 \   'executable_callback': 'ale_linters#pyrex#cython#GetExecutable',
 \   'command_callback': 'ale_linters#pyrex#cython#GetCommand',
-\   'callback': 'ale#handlers#unix#HandleAsError',
+\   'callback': 'ale_linters#pyrex#cython#Handle',
 \})

test/handler/test_pyrex_cython_handler.vader

@@ -0,0 +1,26 @@
+Before:
+  runtime ale_linters/pyrex/cython.vim
+
+After:
+  call ale#linter#Reset()
+
+Execute(The cython handler should handle warnings and errors):
+  AssertEqual
+  \ [
+  \   {
+  \     'lnum': 42,
+  \     'col': 7,
+  \     'text': 'some warning',
+  \     'type': 'W',
+  \   },
+  \   {
+  \     'lnum': 777,
+  \     'col': 21,
+  \     'text': 'some error',
+  \     'type': 'E',
+  \   },
+  \ ],
+  \ ale_linters#pyrex#cython#Handle(347, [
+  \   'warning: file:42:7: some warning',
+  \   'file:777:21: some error',
+  \ ])