Merge pull request #1697 from ananace/add-puppet-languageserver

puppet: Add puppet-languageserver linter

README.md

@@ -157,7 +157,7 @@ formatting.
 | Pony | [ponyc](https://github.com/ponylang/ponyc) |
 | proto | [protoc-gen-lint](https://github.com/ckaznocha/protoc-gen-lint) |
 | Pug | [pug-lint](https://github.com/pugjs/pug-lint) |
-| Puppet | [puppet](https://puppet.com), [puppet-lint](https://puppet-lint.com) |
+| Puppet | [languageserver](https://github.com/lingua-pupuli/puppet-editor-services), [puppet](https://puppet.com), [puppet-lint](https://puppet-lint.com) |
 | Python | [autopep8](https://github.com/hhatto/autopep8), [black](https://github.com/ambv/black), [flake8](http://flake8.pycqa.org/en/latest/), [isort](https://github.com/timothycrosley/isort), [mypy](http://mypy-lang.org/), [prospector](http://github.com/landscapeio/prospector), [pycodestyle](https://github.com/PyCQA/pycodestyle), [pyls](https://github.com/palantir/python-language-server), [pyre](https://github.com/facebook/pyre-check), [pylint](https://www.pylint.org/) !!, [yapf](https://github.com/google/yapf) |
 | QML | [qmlfmt](https://github.com/jesperhh/qmlfmt), [qmllint](https://github.com/qt/qtdeclarative/tree/5.11/tools/qmllint) |
 | R | [lintr](https://github.com/jimhester/lintr) |

ale_linters/puppet/languageserver.vim

@@ -0,0 +1,45 @@
+" Author: Alexander Olofsson <alexander.olofsson@liu.se>
+" Description: Puppet Language Server integration for ALE
+
+call ale#Set('puppet_languageserver_executable', 'puppet-languageserver')
+
+function! ale_linters#puppet#languageserver#GetExecutable(buffer) abort
+    return ale#Var(a:buffer, 'puppet_languageserver_executable')
+endfunction
+
+function! ale_linters#puppet#languageserver#GetCommand(buffer) abort
+    let l:exe = ale#Escape(ale_linters#puppet#languageserver#GetExecutable(a:buffer))
+
+    return l:exe . ' --stdio'
+endfunction
+
+function! ale_linters#puppet#languageserver#GetProjectRoot(buffer) abort
+    " Note: The metadata.json file is recommended for Puppet 4+ modules, but
+    " there's no requirement to have it, so fall back to the other possible
+    " Puppet module directories
+    let l:root_path = ale#path#FindNearestFile(a:buffer, 'metadata.json')
+    if !empty(l:root_path)
+        return fnamemodify(l:root_path, ':h')
+    endif
+
+    for l:test_path in [
+    \   'manifests',
+    \   'templates',
+    \]
+        let l:root_path = ale#path#FindNearestDirectory(a:buffer, l:test_path)
+        if !empty(l:root_path)
+            return fnamemodify(l:root_path, ':h:h')
+        endif
+    endfor
+
+    return ''
+endfunction
+
+call ale#linter#Define('puppet', {
+\   'name': 'languageserver',
+\   'lsp': 'stdio',
+\   'executable_callback': 'ale_linters#puppet#languageserver#GetExecutable',
+\   'command_callback': 'ale_linters#puppet#languageserver#GetCommand',
+\   'language': 'puppet',
+\   'project_root_callback': 'ale_linters#puppet#languageserver#GetProjectRoot',
+\})

doc/ale-puppet.txt

@@ -22,5 +22,16 @@ g:ale_puppet_puppetlint_options               *g:ale_puppet_puppetlint_options*
   puppet-lint invocation.
 
 
+===============================================================================
+puppet-languageserver                               *ale-puppet-languageserver*
+
+g:ale_puppet_languageserver_executable  *g:ale_puppet_languageserver_executable*
+                                        *b:ale_puppet_languageserver_executable*
+  type: |String|
+  Default: `'puppet-languageserver'`
+
+  This variable can be used to specify the executable used for
+  puppet-languageserver.
+
 ===============================================================================
   vim:tw=78:ts=2:sts=2:sw=2:ft=help:norl:

doc/ale.txt

@@ -186,6 +186,7 @@ CONTENTS                                                         *ale-contents*
       puglint.............................|ale-pug-puglint|
     puppet................................|ale-puppet-options|
       puppetlint..........................|ale-puppet-puppetlint|
+      puppet-languageserver...............|ale-puppet-languageserver|
     pyrex (cython)........................|ale-pyrex-options|
       cython..............................|ale-pyrex-cython|
     python................................|ale-python-options|
@@ -391,7 +392,7 @@ Notes:
 * Pony: `ponyc`
 * proto: `protoc-gen-lint`
 * Pug: `pug-lint`
-* Puppet: `puppet`, `puppet-lint`
+* Puppet: `languageserver`, `puppet`, `puppet-lint`
 * Python: `autopep8`, `black`, `flake8`, `isort`, `mypy`, `prospector`, `pycodestyle`, `pyls`, `pyre`, `pylint`!!, `yapf`
 * QML: `qmlfmt`, `qmllint`
 * R: `lintr`

test/test_puppet_path_detection.vader

@@ -0,0 +1,22 @@
+Before:
+  call ale#test#SetDirectory('/testplugin/test')
+
+  runtime ale_linters/puppet/languageserver.vim
+
+After:
+  call ale#test#RestoreDirectory()
+  call ale#linter#Reset()
+
+Execute(old-style module should find its root correctly):
+  call ale#test#SetFilename('puppet-test-files/old-style-module/manifests/init.pp')
+
+  AssertEqual
+  \ ale#path#Simplify(g:dir . '/puppet-test-files/old-style-module'),
+  \ ale_linters#puppet#languageserver#GetProjectRoot(bufnr(''))
+
+Execute(new-style module should find its root correctly):
+  call ale#test#SetFilename('puppet-test-files/new-style-module/lib/puppet/types/exampletype.rb')
+
+  AssertEqual
+  \ ale#path#Simplify(g:dir . '/puppet-test-files/new-style-module'),
+  \ ale_linters#puppet#languageserver#GetProjectRoot(bufnr(''))