From b66b6f925acaa6e44a4110dc3b269630045462e2 Mon Sep 17 00:00:00 2001
From: w0rp <devw0rp@gmail.com>
Date: Sun, 18 Sep 2016 19:33:33 +0100
Subject: [PATCH] Add support for checking C code with GCC too.

---
 README.md             |  1 +
 ale_linters/c/gcc.vim | 49 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)
 create mode 100644 ale_linters/c/gcc.vim

diff --git a/README.md b/README.md
index 05ad5426..40ad9d63 100644
--- a/README.md
+++ b/README.md
@@ -27,6 +27,7 @@ name. That seems to be the fairest way to arrange this table.
 | -------- | ----- |
 | Bash | [-n flag](https://www.gnu.org/software/bash/manual/bash.html#index-set) |
 | Bourne Shell | [-n flag](http://linux.die.net/man/1/sh) |
+| C | [gcc](https://gcc.gnu.org/) |
 | D | [dmd](https://dlang.org/dmd-linux.html) |
 | Fortran | [gcc](https://gcc.gnu.org/) |
 | JavaScript | [eslint](http://eslint.org/), [jscs](http://jscs.info/), [jshint](http://jshint.com/) |
diff --git a/ale_linters/c/gcc.vim b/ale_linters/c/gcc.vim
new file mode 100644
index 00000000..6bd335d8
--- /dev/null
+++ b/ale_linters/c/gcc.vim
@@ -0,0 +1,49 @@
+if exists('g:loaded_ale_linters_c_gcc')
+    finish
+endif
+
+let g:loaded_ale_linters_c_gcc = 1
+
+" Set this option to change the GCC options for warnings for C.
+if !exists('g:ale_c_gcc_options')
+    let g:ale_c_gcc_options = '-Wall'
+endif
+
+function! ale_linters#c#gcc#Handle(buffer, lines)
+    " Look for lines like the following.
+    "
+    " <stdin>:8:5: warning: conversion lacks type at end of format [-Wformat=]
+    " <stdin>:10:27: error: invalid operands to binary - (have ‘int’ and ‘char *’)
+    let pattern = '^<stdin>:\(\d\+\):\(\d\+\): \(warning\|error\): \(.\+\)$'
+    let output = []
+
+    for line in a:lines
+        let l:match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'vcol': 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[4],
+        \   'type': l:match[3] ==# 'warning' ? 'W' : 'E',
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('c', {
+\   'name': 'gcc',
+\   'output_stream': 'stderr',
+\   'executable': 'gcc',
+\   'command': 'gcc -S -x c -fsyntax-only '
+\       . g:ale_c_gcc_options
+\       . ' -',
+\   'callback': 'ale_linters#c#gcc#Handle',
+\})