# Rust test needs to be built after because the web crate depends on js-build
build: fmt js-build rust-build rust-test

rust-test:
    cargo test --all
    cargo fmt --all --check

rust-build: output-clean js-build
    cargo build --all
    cargo build -p web --release --target x86_64-unknown-linux-musl
    earthly +rust-image

wasm-build:
    wasm-pack build --target web xpin-wasm

wordlist-build:
    . wordlist/venv/bin/activate && cd wordlist && for i in *.py; do "./${i}"; done

js-build: wasm-build docs-build
    yarn --cwd ./web-frontend/ build
    rsync -ha ./web-frontend/build/ ./build/

output-clean:
    rm -vrf build
    mkdir build

docs-build: output-clean
    earthly +docs
    cargo doc --all

# TODO: Clippy
rust-watch:
    cargo watch -x fmt -x check -x build

js-dev:
    yarn --cwd ./web-frontend/ dev

fmt:
    # just --fmt --unstable
    cargo fmt --all
    yarn --cwd ./web-frontend/ format

serve:
    http-server --verbose ./web-frontend/build/

init:
    yarn --cwd ./web-frontend/
    cargo fetch
    cargo install wasm-pack

init-python:
    if [ ! -d "wordlist/venv" ]; then python3 -m virtualenv wordlist/venv -p "$(which python3)"; fi; export OSTYPE=linux-gnu && . wordlist/venv/bin/activate
    export OSTYPE=linux-gnu && . wordlist/venv/bin/activate && pip install -r wordlist/requirements.txt && python -c 'import nltk; nltk.download('wordnet')'