Added i3 gaps

x11-wm/i3-gaps/Manifest

@@ -0,0 +1 @@
+EBUILD i3-gaps-9999.ebuild 1785 SHA256 621134eb9c23686c5936cdd58701dc09f820ea3f64348f32499b92350265e3c9 SHA512 7b3db5f9492f64ee399af4cf153320086fcf600e62d6cb640520b0045fc9743637c1110cf852ac7d64dcb373af9423dab0249813055c3708c074a4645b42ae04 WHIRLPOOL 3a90b930dfbe8d7ba260c7aa4980a3a97a8ca600cd2e7c2a3b06b35a816492d88ea431578e81199135573d57b85a3d81967a948a1581f9591c81d5516074c3a4

x11-wm/i3-gaps/i3-gaps-9999.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils toolchain-funcs git-2
+
+DESCRIPTION="An improved dynamic tiling window manager"
+HOMEPAGE="http://i3wm.org/"
+SRC_URI=""
+EGIT_REPO_URI="git://github.com/Airblader/i3"
+EGIT_BRANCH="gaps"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="+cairo +pango"
+REQUIRED_USE="pango? ( cairo )"
+
+CDEPEND="dev-libs/libev
+	dev-libs/libpcre
+	>=dev-libs/yajl-2.0.3
+	x11-libs/libxcb[xkb]
+	x11-libs/libxkbcommon[X]
+	x11-libs/startup-notification
+	x11-libs/xcb-util
+	x11-libs/xcb-util-cursor
+	x11-libs/xcb-util-keysyms
+	x11-libs/xcb-util-wm
+	cairo? (
+		>=x11-libs/cairo-1.14.4[X,xcb]
+	)
+	pango? (
+		>=x11-libs/pango-1.30.0[X]
+	)"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig"
+RDEPEND="${CDEPEND}
+	dev-lang/perl
+	dev-perl/AnyEvent-I3
+	dev-perl/JSON-XS"
+
+DOCS=( RELEASE-NOTES-${PV} )
+
+src_prepare() {
+	if ! use pango; then
+		sed -e '/^PANGO_.*pangocairo/d' \
+		    -e '/PANGO_SUPPORT/ s/1/0/g' \
+			-i common.mk || die
+	fi
+
+	if ! use cairo; then
+		sed -e '/^PANGO_.*cairo/d' \
+		    -e '/CAIRO_SUPPORT/ s/1/0/g' \
+			-i common.mk || die
+	fi
+
+	cat <<- EOF > "${T}"/i3wm
+		#!/bin/sh
+		exec /usr/bin/i3
+	EOF
+	sed -e 's/FALSE/false/' -i src/handlers.c || die #546444
+	epatch_user #471716
+}
+
+src_compile() {
+	emake V=1 CC="$(tc-getCC)" AR="$(tc-getAR)"
+}
+
+src_install() {
+	default
+	dohtml -r docs/*
+	doman man/*.1
+	exeinto /etc/X11/Sessions
+	doexe "${T}"/i3wm
+}
+
+pkg_postinst() {
+	einfo "There are several packages that you may find useful with ${PN} and"
+	einfo "their usage is suggested by the upstream maintainers, namely:"
+	einfo "  x11-misc/dmenu"
+	einfo "  x11-misc/i3status"
+	einfo "  x11-misc/i3lock"
+	einfo "Please refer to their description for additional info."
+}